source: Xerces/m4/xerces_curl_prefix.m4 @ 835

Last change on this file since 835 was 721, checked in by lindanl, 9 years ago

Add the original Xerces code (version 3.1.1)

File size: 3.0 KB
Line 
1dnl @synopsis XERCES_CURL_PREFIX
2dnl
3dnl Determines the prefix for libcurl
4dnl
5dnl @category C
6dnl @author James Berry
7dnl @version 2005-05-23
8dnl @license AllPermissive
9dnl
10dnl $Id: xerces_curl_prefix.m4 883272 2009-11-23 08:17:49Z borisk $
11
12AC_DEFUN([XERCES_CURL_PREFIX],
13        [
14        AC_ARG_WITH([curl],
15                [AS_HELP_STRING([--with-curl[[[[=DIR]]]]],[Specify location of libcurl])],
16                [
17                  if test x"$with_curl" = x"yes"; then
18                    with_curl=
19                  fi
20                ],
21                [with_curl=])
22
23        # Determine if curl is available
24        AC_CACHE_VAL([xerces_cv_curl_present],
25        [
26                xerces_cv_curl_present=no
27                if test x"$with_curl" != x"no"; then
28
29                  # See if we were given a prefix.
30                  #
31                  if test -n "$with_curl"; then
32                    AC_PATH_PROG([curl_config], [curl-config],[],[$with_curl/bin])
33                  else
34                    AC_PATH_PROG([curl_config], [curl-config],[])
35                  fi
36
37                  if test -n "$curl_config"; then
38                    curl_flags=`$curl_config --cflags`
39                    curl_libs=`$curl_config --libs`
40                  else
41                    if test -n "$with_curl"; then
42                      curl_flags="-I$with_curl/include"
43                      curl_libs="-L$with_curl/lib -lcurl"
44                    else
45                      # Default compiler paths.
46                      #
47                      curl_flags=
48                      curl_libs=-lcurl
49                    fi
50                  fi
51
52                  # Check that the headers exist and can be compiled.
53                  #
54                  orig_cppflags=$CPPFLAGS
55                  if test -n "$curl_flags"; then
56                    CPPFLAGS="$curl_flags $CPPFLAGS"
57                  fi
58                  AC_CHECK_HEADER([curl/curl.h], [xerces_cv_curl_present=yes])
59                  CPPFLAGS=$orig_cppflags
60
61                  if test x"$xerces_cv_curl_present" != x"no"; then
62
63                    # Check that the library can be linked.
64                    #
65                    AC_MSG_CHECKING([for curl_multi_init in -lcurl])
66
67                    orig_ldflags=$LDFLAGS
68                    LDFLAGS="$curl_libs $LDFLAGS"
69
70                    AC_LINK_IFELSE(
71                    AC_LANG_SOURCE[[
72                    #include <curl/curl.h>
73                    #include <curl/multi.h>
74                    #include <curl/easy.h>
75
76                    int main ()
77                    {
78                      curl_multi_init();
79                      return 0;
80                    }
81                    ]],
82                    [], [xerces_cv_curl_present=no])
83
84                    LDFLAGS=$orig_ldflags
85
86                    if test x"$xerces_cv_curl_present" != x"no"; then
87                      AC_MSG_RESULT([yes])
88                    else
89                      AC_MSG_RESULT([no])
90                    fi
91                  fi
92                fi
93        ])
94
95        AC_CACHE_VAL([xerces_cv_curl_flags], [xerces_cv_curl_flags=$curl_flags])
96        AC_CACHE_VAL([xerces_cv_curl_libs], [xerces_cv_curl_libs=$curl_libs])
97
98        AC_SUBST([CURL_PRESENT], [$xerces_cv_curl_present])
99        AC_SUBST([CURL_FLAGS], [$xerces_cv_curl_flags])
100        AC_SUBST([CURL_LIBS], [$xerces_cv_curl_libs])
101        ]
102)
Note: See TracBrowser for help on using the repository browser.