source: parabix-LLVM/llvm_git/CMakeLists.txt @ 4136

Last change on this file since 4136 was 4078, checked in by linmengl, 5 years ago

checkin llvm-meng source

File size: 19.8 KB
Line 
1# See docs/CMake.html for instructions about how to build LLVM with CMake.
2
3cmake_minimum_required(VERSION 2.8.8)
4
5# FIXME: It may be removed when we use 2.8.12.
6if(CMAKE_VERSION VERSION_LESS 2.8.12)
7  # Invalidate a couple of keywords.
8  set(cmake_2_8_12_INTERFACE)
9  set(cmake_2_8_12_PRIVATE)
10else()
11  # Use ${cmake_2_8_12_KEYWORD} intead of KEYWORD in target_link_libraries().
12  set(cmake_2_8_12_INTERFACE INTERFACE)
13  set(cmake_2_8_12_PRIVATE PRIVATE)
14  if(POLICY CMP0022)
15    cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
16  endif()
17endif()
18
19project(LLVM)
20
21# Add path for custom modules
22set(CMAKE_MODULE_PATH
23  ${CMAKE_MODULE_PATH}
24  "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
25  "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
26  )
27
28set(LLVM_VERSION_MAJOR 3)
29set(LLVM_VERSION_MINOR 5)
30set(LLVM_VERSION_PATCH 0)
31
32if (NOT PACKAGE_VERSION)
33  set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}svn")
34endif()
35
36option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
37
38option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
39if ( LLVM_USE_FOLDERS )
40  set_property(GLOBAL PROPERTY USE_FOLDERS ON)
41endif()
42
43include(VersionFromVCS)
44
45option(LLVM_APPEND_VC_REV
46  "Append the version control system revision id to LLVM version" OFF)
47
48if( LLVM_APPEND_VC_REV )
49  add_version_info_from_vcs(PACKAGE_VERSION)
50endif()
51
52set(PACKAGE_NAME LLVM)
53set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
54set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
55
56set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
57  "Default URL where bug reports are to be submitted.")
58
59# Configure CPack.
60set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
61set(CPACK_PACKAGE_VENDOR "LLVM")
62set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
63set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
64set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
65set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
66set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
67if(WIN32 AND NOT UNIX)
68  set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
69  set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
70  set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
71  set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
72  set(CPACK_NSIS_MODIFY_PATH "ON")
73  set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
74  set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
75    "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
76  set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
77    "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
78endif()
79include(CPack)
80
81# Sanity check our source directory to make sure that we are not trying to
82# generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
83# sure that we don't have any stray generated files lying around in the tree
84# (which would end up getting picked up by header search, instead of the correct
85# versions).
86if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
87  message(FATAL_ERROR "In-source builds are not allowed.
88CMake would overwrite the makefiles distributed with LLVM.
89Please create a directory and run cmake from there, passing the path
90to this source directory as the last argument.
91This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
92Please delete them.")
93endif()
94if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
95  file(GLOB_RECURSE
96    tablegenned_files_on_include_dir
97    "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
98  file(GLOB_RECURSE
99    tablegenned_files_on_lib_dir
100    "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
101  if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
102    message(FATAL_ERROR "Apparently there is a previous in-source build,
103probably as the result of running `configure' and `make' on
104${CMAKE_CURRENT_SOURCE_DIR}.
105This may cause problems. The suspicious files are:
106${tablegenned_files_on_lib_dir}
107${tablegenned_files_on_include_dir}
108Please clean the source directory.")
109  endif()
110endif()
111
112string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
113
114# They are used as destination of target generators.
115set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
116set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib)
117
118# Each of them corresponds to llvm-config's.
119set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
120set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
121set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
122set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
123set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
124
125set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
126set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
127set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
128
129set(LLVM_ALL_TARGETS
130  AArch64
131  ARM
132  CppBackend
133  Hexagon
134  Mips
135  MSP430
136  NVPTX
137  PowerPC
138  R600
139  Sparc
140  SystemZ
141  X86
142  XCore
143  )
144
145# List of targets with JIT support:
146set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
147
148set(LLVM_TARGETS_TO_BUILD "all"
149    CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
150
151set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
152  CACHE STRING "Semicolon-separated list of experimental targets to build.")
153
154option(BUILD_SHARED_LIBS
155  "Build all libraries as shared libraries instead of static" OFF)
156
157option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
158if(LLVM_ENABLE_TIMESTAMPS)
159  set(ENABLE_TIMESTAMPS 1)
160endif()
161
162option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
163if(LLVM_ENABLE_BACKTRACES)
164  set(ENABLE_BACKTRACES 1)
165endif()
166
167option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
168if(LLVM_ENABLE_CRASH_OVERRIDES)
169  set(ENABLE_CRASH_OVERRIDES 1)
170endif()
171
172option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
173set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
174set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
175
176set(LLVM_TARGET_ARCH "host"
177  CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
178
179option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
180
181option(LLVM_ENABLE_THREADS "Use threads if available." ON)
182
183option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
184
185if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
186  set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
187endif()
188
189set(LLVM_TARGETS_TO_BUILD
190   ${LLVM_TARGETS_TO_BUILD}
191   ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
192list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
193
194include(AddLLVMDefinitions)
195
196option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
197
198# MSVC has a gazillion warnings with this.
199if( MSVC )
200  option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
201else()
202  option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
203endif()
204
205option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
206option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
207option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
208option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
209
210if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
211  option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
212else()
213  option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
214endif()
215
216option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
217       "Set to ON to force using an old, unsupported host toolchain." OFF)
218
219option(LLVM_USE_INTEL_JITEVENTS
220  "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
221  OFF)
222
223if( LLVM_USE_INTEL_JITEVENTS )
224  # Verify we are on a supported platform
225  if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
226    message(FATAL_ERROR
227      "Intel JIT API support is available on Linux and Windows only.")
228  endif()
229endif( LLVM_USE_INTEL_JITEVENTS )
230
231option(LLVM_USE_OPROFILE
232  "Use opagent JIT interface to inform OProfile about JIT code" OFF)
233
234# If enabled, verify we are on a platform that supports oprofile.
235if( LLVM_USE_OPROFILE )
236  if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
237    message(FATAL_ERROR "OProfile support is available on Linux only.")
238  endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
239endif( LLVM_USE_OPROFILE )
240
241set(LLVM_USE_SANITIZER "" CACHE STRING
242  "Define the sanitizer used to build binaries and tests.")
243
244option(LLVM_USE_SPLIT_DWARF
245  "Use -gsplit-dwarf when compiling llvm." OFF)
246
247# Define an option controlling whether we should build for 32-bit on 64-bit
248# platforms, where supported.
249if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
250  # TODO: support other platforms and toolchains.
251  option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
252endif()
253
254# Define the default arguments to use with 'lit', and an option for the user to
255# override.
256set(LIT_ARGS_DEFAULT "-sv")
257if (MSVC OR XCODE)
258  set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
259endif()
260set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
261
262# On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
263if( WIN32 AND NOT CYGWIN )
264  set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
265endif()
266
267# Define options to control the inclusion and default build behavior for
268# components which may not strictly be necessary (tools, examples, and tests).
269#
270# This is primarily to support building smaller or faster project files.
271option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
272option(LLVM_BUILD_TOOLS
273  "Build the LLVM tools. If OFF, just generate build targets." ON)
274
275option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
276
277option(LLVM_BUILD_RUNTIME
278  "Build the LLVM runtime libraries." ON)
279option(LLVM_BUILD_EXAMPLES
280  "Build the LLVM example programs. If OFF, just generate build targets." OFF)
281option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
282
283option(LLVM_BUILD_TESTS
284  "Build LLVM unit tests. If OFF, just generate build targets." OFF)
285option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
286
287option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
288option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
289option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
290option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
291
292option (LLVM_BUILD_EXTERNAL_COMPILER_RT
293  "Build compiler-rt as an external project." OFF)
294
295# All options referred to from HandleLLVMOptions have to be specified
296# BEFORE this include, otherwise options will not be correctly set on
297# first cmake run
298include(config-ix)
299
300# By default, we target the host, but this can be overridden at CMake
301# invocation time.
302set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
303  "Default target for which LLVM will generate code." )
304set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
305
306include(HandleLLVMOptions)
307
308# Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
309set(Python_ADDITIONAL_VERSIONS 2.7 2.6 2.5)
310include(FindPythonInterp)
311if( NOT PYTHONINTERP_FOUND )
312  message(FATAL_ERROR
313"Unable to find Python interpreter, required for builds and testing.
314
315Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
316endif()
317
318######
319# LLVMBuild Integration
320#
321# We use llvm-build to generate all the data required by the CMake based
322# build system in one swoop:
323#
324#  - We generate a file (a CMake fragment) in the object root which contains
325#    all the definitions that are required by CMake.
326#
327#  - We generate the library table used by llvm-config.
328#
329#  - We generate the dependencies for the CMake fragment, so that we will
330#    automatically reconfigure outselves.
331
332set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
333set(LLVMCONFIGLIBRARYDEPENDENCIESINC
334  "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
335set(LLVMBUILDCMAKEFRAG
336  "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
337
338# Create the list of optional components that are enabled
339if (LLVM_USE_INTEL_JITEVENTS)
340  set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
341endif (LLVM_USE_INTEL_JITEVENTS)
342if (LLVM_USE_OPROFILE)
343  set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
344endif (LLVM_USE_OPROFILE)
345
346message(STATUS "Constructing LLVMBuild project information")
347execute_process(
348  COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
349            --native-target "${LLVM_NATIVE_ARCH}"
350            --enable-targets "${LLVM_TARGETS_TO_BUILD}"
351            --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
352            --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
353            --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
354            OUTPUT_VARIABLE LLVMBUILDOUTPUT
355            ERROR_VARIABLE LLVMBUILDERRORS
356            OUTPUT_STRIP_TRAILING_WHITESPACE
357            ERROR_STRIP_TRAILING_WHITESPACE
358  RESULT_VARIABLE LLVMBUILDRESULT)
359
360# On Win32, CMake doesn't properly handle piping the default output/error
361# streams into the GUI console. So, we explicitly catch and report them.
362if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
363  message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
364endif()
365if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
366  message(FATAL_ERROR
367    "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
368endif()
369
370# Include the generated CMake fragment. This will define properties from the
371# LLVMBuild files in a format which is easy to consume from CMake, and will add
372# the dependencies so that CMake will reconfigure properly when the LLVMBuild
373# files change.
374include(${LLVMBUILDCMAKEFRAG})
375
376######
377
378# Configure all of the various header file fragments LLVM uses which depend on
379# configuration variables.
380set(LLVM_ENUM_TARGETS "")
381set(LLVM_ENUM_ASM_PRINTERS "")
382set(LLVM_ENUM_ASM_PARSERS "")
383set(LLVM_ENUM_DISASSEMBLERS "")
384foreach(t ${LLVM_TARGETS_TO_BUILD})
385  set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
386
387  list(FIND LLVM_ALL_TARGETS ${t} idx)
388  list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
389  if( idx LESS 0 AND idy LESS 0 )
390    message(FATAL_ERROR "The target `${t}' does not exist.
391    It should be one of\n${LLVM_ALL_TARGETS}")
392  else()
393    set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
394  endif()
395
396  file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
397  if( asmp_file )
398    set(LLVM_ENUM_ASM_PRINTERS
399      "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
400  endif()
401  if( EXISTS ${td}/AsmParser/CMakeLists.txt )
402    set(LLVM_ENUM_ASM_PARSERS
403      "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
404  endif()
405  if( EXISTS ${td}/Disassembler/CMakeLists.txt )
406    set(LLVM_ENUM_DISASSEMBLERS
407      "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
408  endif()
409endforeach(t)
410
411# Produce the target definition files, which provide a way for clients to easily
412# include various classes of targets.
413configure_file(
414  ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
415  ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
416  )
417configure_file(
418  ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
419  ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
420  )
421configure_file(
422  ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
423  ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
424  )
425configure_file(
426  ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
427  ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
428  )
429
430# Configure the three LLVM configuration header files.
431configure_file(
432  ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
433  ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
434configure_file(
435  ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
436  ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
437configure_file(
438  ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
439  ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
440
441# They are not referenced. See set_output_directory().
442set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
443set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
444set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
445
446set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
447if (APPLE)
448  set(CMAKE_INSTALL_NAME_DIR "@rpath")
449  set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
450else(UNIX)
451  if(NOT DEFINED CMAKE_INSTALL_RPATH)
452    set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib")
453    if (${CMAKE_SYSTEM_NAME} MATCHES FreeBSD)
454      set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-z,origin")
455    endif()
456  endif(NOT DEFINED CMAKE_INSTALL_RPATH)
457endif()
458
459set(CMAKE_INCLUDE_CURRENT_DIR ON)
460
461include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
462
463if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
464  # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
465  # with libxml2, iconv.h, etc., we must add /usr/local paths.
466  include_directories("/usr/local/include")
467  link_directories("/usr/local/lib")
468endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
469
470if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
471   SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
472endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
473
474# Make sure we don't get -rdynamic in every binary. For those that need it,
475# use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
476set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
477
478include(AddLLVM)
479include(TableGen)
480
481if( MINGW )
482  # People report that -O3 is unreliable on MinGW. The traditional
483  # build also uses -O2 for that reason:
484  llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
485endif()
486
487# Put this before tblgen. Else we have a circular dependence.
488add_subdirectory(lib/Support)
489add_subdirectory(lib/TableGen)
490
491add_subdirectory(utils/TableGen)
492
493add_subdirectory(include/llvm)
494
495add_subdirectory(lib)
496
497if( LLVM_INCLUDE_UTILS )
498  add_subdirectory(utils/FileCheck)
499  add_subdirectory(utils/FileUpdate)
500  add_subdirectory(utils/PerfectShuffle)
501  add_subdirectory(utils/count)
502  add_subdirectory(utils/not)
503  add_subdirectory(utils/llvm-lit)
504  add_subdirectory(utils/yaml-bench)
505else()
506  if ( LLVM_INCLUDE_TESTS )
507    message(FATAL_ERROR "Including tests when not building utils will not work.
508    Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
509  endif()
510endif()
511
512if(LLVM_INCLUDE_TESTS)
513  add_subdirectory(utils/unittest)
514endif()
515
516add_subdirectory(projects)
517
518option(WITH_POLLY "Build LLVM with Polly" ON)
519option(LINK_POLLY_INTO_TOOLS "Static link Polly into tools" OFF)
520
521if(WITH_POLLY)
522  if(NOT EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
523    set(WITH_POLLY OFF)
524  endif()
525endif(WITH_POLLY)
526
527if( LLVM_INCLUDE_TOOLS )
528  add_subdirectory(tools)
529endif()
530
531if( LLVM_INCLUDE_EXAMPLES )
532  add_subdirectory(examples)
533endif()
534
535if( LLVM_INCLUDE_TESTS )
536  add_subdirectory(test)
537  add_subdirectory(unittests)
538  if (MSVC)
539    # This utility is used to prevent crashing tests from calling Dr. Watson on
540    # Windows.
541    add_subdirectory(utils/KillTheDoctor)
542  endif()
543
544  # Add a global check rule now that all subdirectories have been traversed
545  # and we know the total set of lit testsuites.
546  get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
547  get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
548  get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
549  get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
550  add_lit_target(check-all
551    "Running all regression tests"
552    ${LLVM_LIT_TESTSUITES}
553    PARAMS ${LLVM_LIT_PARAMS}
554    DEPENDS ${LLVM_LIT_DEPENDS}
555    ARGS ${LLVM_LIT_EXTRA_ARGS}
556    )
557endif()
558
559if (LLVM_INCLUDE_DOCS)
560  add_subdirectory(docs)
561endif()
562
563add_subdirectory(cmake/modules)
564
565if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
566  install(DIRECTORY include/llvm include/llvm-c
567    DESTINATION include
568    FILES_MATCHING
569    PATTERN "*.def"
570    PATTERN "*.h"
571    PATTERN "*.td"
572    PATTERN "*.inc"
573    PATTERN "LICENSE.TXT"
574    PATTERN ".svn" EXCLUDE
575    )
576
577  install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
578    DESTINATION include
579    FILES_MATCHING
580    PATTERN "*.def"
581    PATTERN "*.h"
582    PATTERN "*.gen"
583    PATTERN "*.inc"
584    # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
585    PATTERN "CMakeFiles" EXCLUDE
586    PATTERN ".svn" EXCLUDE
587    )
588endif()
Note: See TracBrowser for help on using the repository browser.